CMake：打印出脚本中所有可访问的变量

使用 get_cmake_property 函数，以下循环将打印出所有定义的 CMake 变量及其值：

get_cmake_property(_variableNames VARIABLES)
list (SORT _variableNames)
foreach (_variableName ${_variableNames})
    message(STATUS "${_variableName}=${${_variableName}}")
endforeach()

这也可以嵌入到一个便利函数中，该函数可以选择使用正则表达式仅打印具有匹配名称的变量子集

function(dump_cmake_variables)
    get_cmake_property(_variableNames VARIABLES)
    list (SORT _variableNames)
    foreach (_variableName ${_variableNames})
        if (ARGV0)
            unset(MATCHED)
            string(REGEX MATCH ${ARGV0} MATCHED ${_variableName})
            if (NOT MATCHED)
                continue()
            endif()
        endif()
        message(STATUS "${_variableName}=${${_variableName}}")
    endforeach()
endfunction()

要打印环境变量，请使用 CMake 的 command mode：

execute_process(COMMAND "${CMAKE_COMMAND}" "-E" "environment")

另一种方法是简单地使用：

cmake -LAH

从 manpage：

-L[A][H] 列出非高级缓存变量。列出缓存变量将运行 CMake 并列出 CMake 缓存中未标记为 INTERNAL 或 ADVANCED 的所有变量。这将有效地显示当前的 CMake 设置 [...]。如果指定了 A，那么它还将显示高级变量。如果指定了 H，它还将显示每个变量的帮助。

ccmake 是交互式检查缓存变量（option( 或 set( CACHE）的一个很好的交互式选项：

sudo apt-get install cmake-curses-gui
mkdir build
cd build
cmake ..
ccmake ..

https://i.stack.imgur.com/ohmjl.png

查看所有 cmake 内部变量的另一种方法是使用 --trace-expand 选项执行 cmake。

这将为您提供所有已执行的 .cmake 文件和在每一行上设置的变量的跟踪。

基于@sakra

function(dump_cmake_variables)
    get_cmake_property(_variableNames VARIABLES)
    list (SORT _variableNames)
    foreach (_variableName ${_variableNames})
        if (ARGV0)
            unset(MATCHED)

            #case sensitive match
            # string(REGEX MATCH ${ARGV0} MATCHED ${_variableName})
            #
            #case insenstitive match
            string( TOLOWER "${ARGV0}" ARGV0_lower )
            string( TOLOWER "${_variableName}" _variableName_lower )
            string(REGEX MATCH ${ARGV0_lower} MATCHED ${_variableName_lower})

            if (NOT MATCHED)
                continue()
            endif()
        endif()
        message(STATUS "${_variableName}=${${_variableName}}")
    endforeach()
endfunction()

dump_cmake_variables("^Boost")

变量名区分大小写

顺便说一句，如果您对 boost 感兴趣，它是 Boost_INCLUDE_DIRS 而不是 BOOST_INCLUDE_DIRS，它是 Boost_LIBRARIES 而不是 BOOST_LIBRARIES，并且我错误地使用了 BOOST_LIBRARIES 而不是 Boost_LIBRARIES，https://cmake.org/cmake/help/v3.0/module/FindBoost.html，这是 boost 的更好示例：

set(Boost_USE_STATIC_LIBS ON)
find_package(Boost REQUIRED COMPONENTS RANDOM)
include_directories(${Boost_INCLUDE_DIRS})

target_link_libraries(myfile PRIVATE
 ${Boost_LIBRARIES}
)

当前的答案都不允许我查看项目子目录中的变量。这是一个解决方案：

function(print_directory_variables dir)
    # Dump variables:
    get_property(_variableNames DIRECTORY ${dir} PROPERTY VARIABLES)
    list (SORT _variableNames)
    foreach (_variableName ${_variableNames})
        get_directory_property(_variableValue DIRECTORY ${dir} DEFINITION ${_variableName})
        message(STATUS "DIR ${dir}: ${_variableName}=${_variableValue}")
    endforeach()
endfunction(print_directory_variables)

# for example
print_directory_variables(.)
print_directory_variables(ui/qt)

您可以使用 message ：

message([STATUS] "SUB_SOURCES : ${SUB_SOURCES}")