如何在 CMake 的 try_compile 函数中为 OpenMP 设置链接器标志

CMake 有一个 standard module 用于测试编译器是否支持 OpenMP：

find_package(OpenMP)
if (OPENMP_FOUND)
    set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${OpenMP_C_FLAGS}")
    set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${OpenMP_CXX_FLAGS}")
    set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${OpenMP_EXE_LINKER_FLAGS}")
endif()

注意：
对于当前 CMake 版本，不建议再使用此答案将 OpenMP 包含在项目中。参考其他答案。

---

从 CMake 3.9 开始，每种语言都有导入的 OpenMP 目标。我认为这是一个更优雅的解决方案。这是 C++ 中的一个示例：

cmake_minimum_required(VERSION 3.9)
project(solver LANGUAGES CXX)

find_package(OpenMP REQUIRED)
add_executable(solver solver.cc)
target_link_libraries(solver PRIVATE OpenMP::OpenMP_CXX)

这更方便，因为它减少了输入，这样您就不必调整容易出错的编译标志、库等。这就是现代 CMake 的发展方向。

如果您使用的是 CMake 3.9 之前的版本，我仍然不推荐使用 currently accepted answer。我相信为每个目标设置标志更好：

add_executable(solver solver.cc)
target_link_libraries(solver PRIVATE "${OpenMP_CXX_FLAGS}")
target_compile_options(solver PRIVATE "${OpenMP_CXX_FLAGS}")

这可能不适用于某些编译器；这也是 CMake 在 CMake 3.9 中改进其 OpenMP 支持的部分原因。

---

CMake 3.9+ 中改进了对 OpenMP 的支持

CMakeLists.txt

cmake_minimum_required(VERSION 3.9)
project(openmp_test) # you can change the project name

find_package(OpenMP)

add_executable(openmp_para_test main.cpp) # you can change the excutable name

if(OpenMP_CXX_FOUND)
    target_link_libraries(openmp_para_test PUBLIC OpenMP::OpenMP_CXX)
endif()

如果需要，这种方式将正确设置与编译行不同的库链接行。

Source。

---

如果您尝试使用 g++ 的“现代”方式，您也可以这样做：

find_package(OpenMP REQUIRED)

add_executable(Foo foo.cpp)
target_compile_options(Foo PRIVATE -Wall ${OpenMP_CXX_FLAGS})
target_link_libraries(Foo PRIVATE ${OpenMP_CXX_FLAGS})

注意：

如果您只遗漏 target_compile_options 您的编译指示将被简单地忽略（启用的警告会告诉您）如果您只遗漏 target_link_libraries 您的代码将无法编译，因为 g++ 没有正确链接如果您将两者都遗漏了 1. note 适用于呈现不再需要的链接，并且您的代码将编译。

我不知道这种将“hack”与标志链接起来是否也适用于其他编译器。

---